GFN-xTBを使う

メモ書きです。

最新のORCAにはGrimmeらのGFN-xTBプログラムが同梱されています。実行ファイルとしてはotool_xtbがこれに相当し、非常に高速な構造最適化や振動解析、MD等が実施可能です。-hオプションで簡単なマニュアルは見ることができます。構造最適化をxTBに投げる簡単なバッチファイルを組みました。

@echo off
title GFN2-xTB (in ORCA 4.1.0)
set filecount=0
set /P syschg="系の電荷を入力してください(defaultは0)："
if '%syschg%'=='' set syschg=0
set /P solvnt="GBモデルで考慮する溶媒名を入力してください(defaultはなし)："
if not '%solvnt%'=='' set solvnt=-g %solvnt%
:start
if '%1'=='' goto end

rem Windows⇔Bash(Ubuntu)パス変換ブロック
set winpath=%~dpn1
for /f %%i in ('wsl wslpath "%winpath%"') do set linpath=%%i

rem プログラム実行ブロック
set /A filecount=%filecount%+1
echo.
echo 《 Job #%filecount% : %~n1 》
echo     start : %date% %time%
mkdir %~dp1\xTBtemp
copy %1 %~dp1\xTBtemp\input.xyz > nul
cd /D %~dp1\xTBtemp > nul
bash -c "otool_xtb input.xyz -o -c %syschg% %solvnt% -P 6 1> %linpath%.log"
copy xtbopt.xyz %~p1\%~n1.opted.xyz > nul
copy xtbopt.log %~p1\%~n1.trj.xyz > nul
cd /D %~dp1 > nul
rmdir /s /q %~dp1\xTBtemp > nul
echo     finish : %date% %time%
echo.
shift
goto start

:end
pause
exit

まぁ、いつもの形の使いまわしです。ちなみに、Hessian計算を並列で実施するとなぜかエラー終了してしまうことが多いため、もし-ohessオプションで実行する場合は-Pは指定しないほうが良いかもです(環境によるのでしょうが)。